COMMENT ⊗   VALID 00006 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	% for testing contributions to APSFIG
C00003 00003	beginchar(1,6cm#,2.6cm#,0) "Figure 3aa"
C00007 00004	def overdraw expr c = erase fill c draw c enddef
C00012 00005	beginchar(10,1in#,1in#,0) "Figure Daa" % warped digitized picture
C00014 00006	end
C00015 ENDMK
C⊗;
% for testing contributions to APSFIG
mode_setup;
standard_pen=savepen;
beginchar(1,6cm#,2.6cm#,0); "Figure 3aa";
pickup standard_pen;
for d=0 step 10 until 120:
 draw (0,0){dir 60}..(6cm,0){dir-d}; endfor
endchar;

beginchar(2,6cm#,1cm#,1.8cm#); "Figure 3bb";
pickup standard_pen;
for d=0 step -10 until -90:
 draw (0,0){dir 60}..(6cm,0){dir-d}; endfor
endchar;

beginchar(3,6cm#,2.6cm#,0); "Figure 3cc";
pickup standard_pen;
for d=0 step 10 until 120:
 draw (0,0){dir 60}...(6cm,0){dir-d}; endfor
endchar;
def overdraw expr c = erase fill c; draw c enddef;
beginchar(4,40pt#,100pt#,0); pickup standard_pen; "Figure 13aa";
path S; S=((0,1)..(2,0)..(4,2)..(2,5.5)..(0,8)..(2,10)..(3.5,9)) scaled 9pt;
for k=0 upto 35: overdraw fullcircle scaled 3mm
 shifted point k/35*length S of S; endfor
endchar;

def overdraw expr c = begingroup picture region; region:=nullpicture;
 interim turningcheck:=0; addto region contour c; cull region dropping (0,0);
 cullit; addto currentpicture also -region; cullit; draw c endgroup enddef;
def link(expr n) = overdraw subpath 1/3(n,n+1) of M --
		subpath 1/3(n+25,n+24) of M -- cycle enddef;
beginchar(5,1.25in#,.5in#,0); pickup standard_pen; "Figure 13bb";
z1=(20,-13); z2=(30,-6); z3=(20,1); z4=(4,-7);
 z5=(-12,-13); z6=(-24,-4); z7=(-15,6);
path M; M=(origin..z1..z2..z3..z4..z5..z6..z7..
	    origin..-z7..-z6..-z5..-z4..-z3..-z2..-z1..cycle)
  scaled (h/26) shifted (.5w,.5h);
for k=1 upto 12: link(k+11); link(12-k); endfor
endchar;
beginchar(10,1in#,1in#,0); "Figure Daa"; % warped digitized picture
sc:=3144.8/655.36pt;
def Tracing=begingroup save :,Tracing,edges,at,weight,w,[,];
 delimiters []; let Tracing = endfill; interim turningcheck:=0;
 let edges = \; let weight = \; let : = \;
 vardef at@#(expr wt) = save (,); w:=wt;
  let ( = lp; let ) = rp; fill[gobble begingroup enddef; enddef;
def lp = [ enddef;
def rp = ]..tension 4.. enddef;
vardef No@# = origin enddef;
def endfill = cycle] scaled sc withweight w endgroup; enddef;
def completed = endgroup; enddef;

Tracing edges at line 15: (weight 1)
(1,5)(1,2)(2,2)(2,1)(3,1)(3,0)(8,0)(8,1)(9,1)(9,2)(10,2)(10,8)(9,8)
(9,9)(8,9)(8,10)(3,10)(3,9)(2,9)(2,8)(1,8)(1,5).
Tracing edges at line 15: (weight -1)
(3,5)(3,2)(4,2)(4,1)(7,1)(7,2)(8,2)(8,8)(7,8)(7,9)(4,9)(4,8)(3,8)(3,5).
Tracing edges completed.
endchar;
end